SQL Index and other Maintenance Plans

Epicor ERP 10
1

My Server & DB guys are looking to optimize our SQL maintenance plans for when we go live with 10.1 Epicor. So I thought I’d pose the question here as I’m no SQL expert on setting reindex plans and setting fill-rates. I’d be happy to pass on any tips you guys have.

Thanks,
Randy

2

Randy,
I have always found Brent Ozar as a good resource and explains this sort of stuff that makes a lot of sense (to me anyway). Here is a link to one of his blogs An Introduction to Fillfactor in SQL Server.
There is a lot of great information in it.

Hope it helps.

3 Likes
3

Brent Ozar Resources are excellent

1 Like
4

We have a maintenance plan setup in SQL that runs the following script then a ‘Full Scan’ for update statistics.

--https://msdn.microsoft.com/en-us/library/ms188917.aspx

USE Epicor10Live

SET NOCOUNT ON;
DECLARE @objectid int;
DECLARE @indexid int;
DECLARE @partitioncount bigint;
DECLARE @schemaname nvarchar(130); 
DECLARE @objectname nvarchar(130); 
DECLARE @indexname nvarchar(130); 
DECLARE @partitionnum bigint;
DECLARE @partitions bigint;
DECLARE @frag float;
DECLARE @command nvarchar(4000); 
-- Conditionally select tables and indexes from the sys.dm_db_index_physical_stats function 
-- and convert object and index IDs to names.
SELECT
    object_id AS objectid,
    index_id AS indexid,
    partition_number AS partitionnum,
    avg_fragmentation_in_percent AS frag
INTO #work_to_do
FROM sys.dm_db_index_physical_stats (DB_ID(), NULL, NULL , NULL, 'LIMITED') 
WHERE avg_fragmentation_in_percent > 10.0 AND index_id > 0 ;

-- Declare the cursor for the list of partitions to be processed.
DECLARE partitions CURSOR FOR SELECT * FROM #work_to_do;

-- Open the cursor.
OPEN partitions;

-- Loop through the partitions.
WHILE (1=1)
    BEGIN;
        FETCH NEXT
           FROM partitions
           INTO @objectid, @indexid, @partitionnum, @frag;
        IF @@FETCH_STATUS < 0 BREAK;
        SELECT @objectname = QUOTENAME(o.name), @schemaname = QUOTENAME(s.name)
        FROM sys.objects AS o
        JOIN sys.schemas as s ON s.schema_id = o.schema_id
        WHERE o.object_id = @objectid;
        SELECT @indexname = QUOTENAME(name)
        FROM sys.indexes
        WHERE  object_id = @objectid AND index_id = @indexid;
        SELECT @partitioncount = count (*)
        FROM sys.partitions
        WHERE object_id = @objectid AND index_id = @indexid;

-- 30 is an arbitrary decision point at which to switch between reorganizing and rebuilding.
        IF @frag < 30.0
           SET @command = N'ALTER INDEX ' + @indexname + N' ON ' + @schemaname + N'.' + @objectname + N' REORGANIZE';
        IF @frag >= 30.0
            SET @command = N'ALTER INDEX ' + @indexname + N' ON ' + @schemaname + N'.' + @objectname + N' REBUILD';
        IF @partitioncount > 1
            SET @command = @command + N' PARTITION=' + CAST(@partitionnum AS nvarchar(10));
        BEGIN TRY
			EXEC (@command);
			PRINT N'Executed: ' + @command;
		END TRY
		BEGIN CATCH
			PRINT N'ERROR: Could not execute: ' + @command;
		END CATCH
    END;

-- Close and deallocate the cursor.
CLOSE partitions;
DEALLOCATE partitions;

-- Drop the temporary table.
DROP TABLE #work_to_do;
GO
4 Likes
5

Nice!

I’ll pass it onto my systems team.

6

@MarkBetts

This script looks promising, ran it on a test database and got the error saying The index “IX_SugPoDtl_BuyToOrderIdx” on table “SugPoDtl” cannot be reorganized because page level locking is disabled

Did you enable page level locking on your indexes in order to run this script, I believe Epicor diables this when generating its indexes?